My Macros: Targeting

  Targeting with macros makes target switching a breeze. I primarily use mouseover and focus macros as well as the occasional target specific macro. The two that I use most are:

/focus target

and

/target focus

  These simple macros are keybound and let me focus a target quickly and switch to a focused target quickly. They're invaluable in clinch situations. Other targeting macros are a bit more complicated, but knowing what each command does allows me to tailor a macroed abilities behavior precisely.

/target mouseover

 The /target mouseover command suits itself well to certain abilities after a bit of practice. I use it with openers like Charge and Serpent Sting to quickly acquire and engage the next target.

Serpent Sting Macro:
#showtooltip
/target mouseover
/use Serpent Sting
/startattack
/petattack

/use [@mouseover][@target][@focus][@player]

  For off targets that you want to hit with something without loosing your target, the [@mouseover] command is useful, if a bit finicky. To prevent trying to silence a teammate or heal an enemy, use [@mouseover,harm] and [@mouseover,help] to specify the type of target. If your mouseover is the opposite of whatever your macro specifies, i.e., mouseover is friendly but the macro says [@mouseover,harm], then the macro will move on to the next command. Following the command with [@target] will then use the ability on your current target. I use this for ranged interrupts, silences, stuns, and slows.


Avenger's Shield Macro:
#showtooltip Avenger's Shield
/use [@mouseover,harm][@target,harm] Avenger's Shield


I also use it for most of my healing abilities, with the added [@player] so that if I have no target and no mouseover, I still cast. This is great for mouseover healing.

Prayer of Healing Macro:
#showtooltip Prayer of Healing
/cast Inner Focus
/use [@mouseover,help][help][@focus][@player] Prayer of Healing

  Then there are certain abilities like Leap of Faith or Pain Suppression that you do not want to use on dead targets. For these, specifying that the target exists will prevent the ability being wasted.

Leap of Faith Macro:
#showtooltip leap of faith
/cast [@mouseover,exists][@target,exists] Leap of Faith

  As a somewhat complicated example:

Power Infusion Macro:
#showtooltip power infusion
/use [@player] power infusion
/use Archangel
/use 13
/use 14
/use inner focus
/use [@mouseover,help][@target,help][@focus,help][@player] Flash Heal

  This macro uses PI on myself, uses archangel, trinkets, and Inner Focus as available, then casts Flash Heal on friendly mouseover target; if none, then then friendly target; if none, then friendly focus; if none, then self. Note that the macro can cast PI on self and Flash Heal on a different target. If I did not include [@player] in that line, it would cast PI on the current target.

/target *name* /targetlasttarget

  Sometimes a specific person should be the recipient of your ability, like using Death Coil to heal Timmy (whatever the current Ghoul's name is) or Misdirecting to someone specific without requiring that target to be focused.

Death Coil Pet Heal Macro:
#showtooltip Death Coil
/target Timmy
/use Death Coil
/targetlasttarget

Misdirection Macro:
#showtooltip Misdirection
/target Badhealer
/use misdirection
/targetlasttarget